CMakeLists.txt

# /****************************************************************************
# Copyright (c) 2013 cocos2d-x.org
# Copyright (c) 2014 martell malone
# Copyright (c) 2015-2017 Chukong Technologies Inc.
# Copyright (c) 2019-present Simdsoft Limited.
#
# https://axmol.dev/
#
# SPDX-License-Identifier: MIT
# ****************************************************************************/

# build engine library and all tests

cmake_minimum_required(VERSION 3.22...4.4)

project(axmol)

if(XCODE)
  set(CMAKE_XCODE_GENERATE_TOP_LEVEL_PROJECT_ONLY TRUE)
endif()

# ax root path
set(_AX_ROOT ${CMAKE_CURRENT_SOURCE_DIR})
set(CMAKE_MODULE_PATH ${_AX_ROOT}/cmake/Modules/)

# prevent in-source-build
include(PreventInSourceBuilds)

# works before build libaxmol
include(AXBuildSet)

option(AX_BUILD_TESTS "Build cpp & lua tests" ON)

# Mark that engine build is invoked from root
set(BUILD_ENGINE_BEGAN ON)

add_subdirectory(${_AX_ROOT}/axmol ${ENGINE_BINARY_PATH}/axmol)

# prevent tests project to build axmol engine again
set(BUILD_ENGINE_DONE ON)

if(AX_BUILD_TESTS)
  enable_testing()
  message(STATUS "CMAKE_BINARY_DIR=${CMAKE_BINARY_DIR}")

  macro(add_test_target target_name dir)
    add_subdirectory(${dir} ${CMAKE_BINARY_DIR}/tests/${target_name})
    set_target_properties(${target_name} PROPERTIES FOLDER "Apps")
  endmacro()

  # add cpp tests default
  add_test_target(cpp-tests ${_AX_ROOT}/tests/cpp-tests)

  if(LINUX OR MACOSX OR WINDOWS)
    add_test_target(unit-tests ${_AX_ROOT}/tests/unit-tests)
  endif()

  # add fairygui tests when fairygui extension is enabled
  if(AX_ENABLE_EXT_FAIRYGUI)
    add_test_target(fairygui-tests ${_AX_ROOT}/tests/fairygui-tests)
  endif()

  if(AX_ENABLE_EXT_LIVE2D)
    add_test_target(live2d-tests ${_AX_ROOT}/tests/live2d-tests)
  endif()

  if(AX_ENABLE_EXT_LUA)
    add_test_target(lua-tests ${_AX_ROOT}/tests/lua-tests)
  endif(AX_ENABLE_EXT_LUA)
endif()