blitz_api/flake.nix at dev · fusion44/blitz_api · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
{
  description = "A management backend for the RaspiBlitz project written in Python / FastAPI";

  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    pyproject-nix = {
      url = "github:pyproject-nix/pyproject.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    uv2nix = {
      url = "github:pyproject-nix/uv2nix";
      inputs = {
        pyproject-nix.follows = "pyproject-nix";
        nixpkgs.follows = "nixpkgs";
      };
    };

    pyproject-build-systems = {
      url = "github:pyproject-nix/build-system-pkgs";
      inputs = {
        pyproject-nix.follows = "pyproject-nix";
        uv2nix.follows = "uv2nix";
        nixpkgs.follows = "nixpkgs";
      };
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    pyproject-nix,
    uv2nix,
    pyproject-build-systems,
  }: let
    name = "blitz-api";
    inherit (nixpkgs) lib;

    workspace = uv2nix.lib.workspace.loadWorkspace {workspaceRoot = ./.;};

    # Prefer prebuilt binary wheels: building grpcio & friends from
    # source is slow and needs extra native build inputs.
    overlay = workspace.mkPyprojectOverlay {
      sourcePreference = "wheel";
    };

    systems = flake-utils.lib.eachDefaultSystem (system: let
      pkgs = nixpkgs.legacyPackages.${system};
      # 3.12 to match devenv.nix; RaspiBlitz 1.12 ships 3.11
      python = pkgs.python312;

      pythonSet =
        (pkgs.callPackage pyproject-nix.build.packages {
          inherit python;
        }).overrideScope (
          lib.composeManyExtensions [
            pyproject-build-systems.overlays.default
            overlay
          ]
        );

      venv = pythonSet.mkVirtualEnv "${name}-env" workspace.deps.default;
    in {
      packages = {
        default = self.packages.${system}.${name};
        # A virtualenv with blitz_api and all of its dependencies.
        # Provides the `api` console script used by the NixOS module.
        ${name} = venv.overrideAttrs (old: {
          meta = (old.meta or {}) // {mainProgram = "api";};
        });
      };

      # Python dependencies are managed impurely via `uv sync` into
      # ./.venv, mirroring devenv.nix; this shell provides the tooling.
      devShells.default = pkgs.mkShell {
        packages = with pkgs; [
          python
          uv

          stdenv.cc.cc
          pyright
          isort
          alejandra
          statix
          ruff
          redis
          nushell
          typos
          typos-lsp
          sshpass

          bitcoind
          lnd
          clightning
        ];

        env = {
          # use the nix-provided interpreter and never download one
          UV_PYTHON = python.interpreter;
          UV_PYTHON_DOWNLOADS = "never";
        };

        shellHook = ''
          unset PYTHONPATH
          export LD_LIBRARY_PATH="$LD_LIBRARY_PATH:${
            lib.makeLibraryPath [pkgs.stdenv.cc.cc.lib]
          }"
        '';
      };
    });

    overlays.overlays = {
      default = final: prev: {
        ${name} = self.packages.${prev.stdenv.hostPlatform.system}.${name};
      };
    };

    module = {
      nixosModules.default = {
        pkgs,
        lib,
        config,
        ...
      }: {
        imports = [./modules/blitz_api.nix];
        nixpkgs.overlays = [self.overlays.default];
      };
    };
  in
    systems // overlays // module;
}