StemFlow/install.bat at main · vtaeely/StemFlow · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
@echo off
chcp 65001 >nul
setlocal EnableExtensions
cd /d "%~dp0"

echo.
echo  StemFlow - установка для Windows 10/11 x64
echo.

where py >nul 2>nul
if errorlevel 1 (
  echo [ОШИБКА] Не найден Python Launcher.
  echo Установите Python 3.11 x64 с https://www.python.org/downloads/
  echo и включите пункт "Add Python to PATH".
  pause
  exit /b 1
)

py -3.11 -c "import sys; assert sys.maxsize > 2**32" >nul 2>nul
if errorlevel 1 (
  echo [ОШИБКА] Нужен Python 3.11 x64.
  pause
  exit /b 1
)

if not exist ".venv\Scripts\python.exe" (
  echo [1/5] Создание виртуального окружения...
  py -3.11 -m venv .venv
  if errorlevel 1 goto :failed
)

set "PY=.venv\Scripts\python.exe"
echo [2/5] Обновление pip...
"%PY%" -m pip install --upgrade pip setuptools wheel
if errorlevel 1 goto :failed

where nvidia-smi >nul 2>nul
if errorlevel 1 (
  echo [3/5] NVIDIA GPU не обнаружен. Устанавливается PyTorch CPU.
  "%PY%" -m pip install torch==2.7.0 torchaudio==2.7.0
) else (
  echo [3/5] Обнаружена NVIDIA GPU. Устанавливается PyTorch CUDA 12.8.
  "%PY%" -m pip install -r requirements-cuda.txt
)
if errorlevel 1 goto :failed

echo [4/5] Установка StemFlow и Demucs...
"%PY%" -m pip install -r requirements.txt
if errorlevel 1 goto :failed

echo [5/5] Проверка FFmpeg...
where ffmpeg >nul 2>nul
if errorlevel 1 (
  echo.
  echo [ВНИМАНИЕ] FFmpeg не найден в PATH.
  echo Установите его командой:
  echo   winget install --id Gyan.FFmpeg -e
  echo Затем закройте и снова откройте терминал.
) else (
  ffmpeg -version | findstr /b "ffmpeg version"
)

echo.
echo Установка завершена. Запуск: run.bat
pause
exit /b 0

:failed
echo.
echo [ОШИБКА] Установка прервана. Смотрите сообщения выше.
pause
exit /b 1