Composite PK support

[jmoore34]

From the docs, it's unclear if Beam supports composite PKs -- i.e. primary keys which reference two or more columns. I imagine there are different ways of doing this (perhaps a product type, perhaps a tuple), but without being too familiar with type families and Beam internals, I'm not able to figure out how to do this

[LaurentRDC]

Hi Jonathan,

Beam does support composite PKs. There's a minimal example below that compiles. This could be added to the documentation more clearly, since we can now generate documentation since #784

Cabal file

cabal-version:      3.0
name:               composite-pk
version:            0.1.0.0

library
  exposed-modules:    CompositePK
  build-depends:
    , base   >= 4.14 && < 5
    , beam-core >= 0.10 && < 0.11
  default-language:   GHC2021

Haskell module

{-# LANGUAGE DeriveAnyClass #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE TypeFamilies #-}

module CompositePK where

import Database.Beam (
  Beamable,
  C,
  Database,
  DatabaseSettings,
  Generic,
  Identity,
  Table (..),
  TableEntity,
  dbModification,
  defaultDbSettings,
  fieldNamed,
  modifyTableFields,
  tableModification,
  withDbModification,
 )

data UserRoleT f = UserRole
  { _userId :: C f Int
  , _roleId :: C f Int
  }
  deriving (Generic, Beamable)

instance Table UserRoleT where
  -- Your 'PrimaryKey' type can be any product type,
  -- with one column or more
  data PrimaryKey UserRoleT f = UserRolePK (C f Int) (C f Int)
    deriving (Generic, Beamable)
  primaryKey ur = UserRolePK (_userId ur) (_roleId ur)

data AuditLogT f = AuditLog
  { _logId :: C f Int
  , -- Embed the entire composite primary key as one record field.
    -- It will be expanded to two columns: granted_user_id + granted_role_id.
    -- The column names are described in the `appDb` settings
    _targetGrant :: PrimaryKey UserRoleT f
  , _action :: C f String
  , _happenedAt :: C f Int
  }
  deriving (Generic, Beamable)

instance Table AuditLogT where
  data PrimaryKey AuditLogT f = AuditLogPK (C f Int)
    deriving (Generic, Beamable)
  primaryKey = AuditLogPK . _logId

data AppDb f = AppDb
  { _userRoles :: f (TableEntity UserRoleT)
  , _auditLogs :: f (TableEntity AuditLogT)
  }
  deriving (Generic, Database be)

appDb :: DatabaseSettings be AppDb
appDb =
  defaultDbSettings
    `withDbModification` dbModification
      { _auditLogs =
          modifyTableFields
            tableModification
              { _logId = fieldNamed "log_id"
              , _targetGrant =
                  UserRolePK
                    -- The two columns to represent the primary key are made explicit
                    -- in database settings
                    (fieldNamed "granted_user_id")
                    (fieldNamed "granted_role_id")
              , _action = fieldNamed "action"
              , _happenedAt = fieldNamed "happened_at"
              }
      }

[jmoore34]

Thanks, this helps